Cleaned the CMake configuration of the project.

Made the same sort of updates as in GeoModelCore. Though things had to be done in an even more complicated way in this project.

Cleaned the CMake configuration of the project.
2d9d4fd5 · Attila Krasznahorkay · 69d6c275 · 2d9d4fd5 · 2d9d4fd5 · 2d9d4fd5
Commit 2d9d4fd5 authored 5 years ago by Attila Krasznahorkay
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
-
+# Copyright (C) 2002-2019 CERN for the benefit of the ATLAS collaboration

 # Set up the project.
 cmake_minimum_required( VERSION 3.1 )
-project( "GeoModelIO" VERSION 1.0.0 LANGUAGES CXX )
+project( "GeoModelIO" VERSION 1.3.0 LANGUAGES CXX )
+
+# Set default build options.
+set( CMAKE_BUILD_TYPE "Release" CACHE STRING "CMake build mode to use" )
+set( CMAKE_CXX_STANDARD 17 CACHE STRING "C++ standard used for the build" )
+set( CMAKE_CXX_EXTENSIONS FALSE CACHE BOOL "(Dis)allow using GNU extensions" )
+set( CMAKE_CXX_STANDARD_REQUIRED TRUE CACHE BOOL
+   "Require the specified C++ standard for the build" )

 # Project's dependencies.
 find_package( GeoModelCore REQUIRED )
+find_package( Qt5 COMPONENTS Core Sql REQUIRED )
+
+# Use the GNU install directory names.
+include( GNUInstallDirs )

 # Set sub-packages to build.
-# add_subdirectory(GeoModelErrorHandler)
-add_subdirectory(GeoModelDBManager)
-add_subdirectory(TFPersistification)
-add_subdirectory(GeoModelRead)
-add_subdirectory(GeoModelWrite)
-
-# Set the export of all the sub-packages' 
-# install(EXPORT GeoModelErrorHandler-export FILE GeoModelIO-GeoModelErrorHandler.cmake DESTINATION lib/GeoModelIO)
-install(EXPORT GeoModelDBManager-export FILE GeoModelIO-GeoModelDBManager.cmake DESTINATION lib/GeoModelIO)
-install(EXPORT TFPersistification-export FILE GeoModelIO-TFPersistification.cmake DESTINATION lib/GeoModelIO)
-install(EXPORT GeoModelRead-export FILE GeoModelIO-GeoModelRead.cmake DESTINATION lib/GeoModelIO)
-install(EXPORT GeoModelWrite-export FILE GeoModelIO-GeoModelWrite.cmake DESTINATION lib/GeoModelIO)
-install(FILES cmake/GeoModelIOConfig.cmake DESTINATION lib/GeoModelIO)
+add_subdirectory( GeoModelErrorHandler )
+add_subdirectory( GeoModelDBManager )
+add_subdirectory( TFPersistification )
+add_subdirectory( GeoModelRead )
+add_subdirectory( GeoModelWrite )
+
+# Create and install the version description of the project.
+include( WriteBasicConfigVersionFile )
+write_basic_config_version_file(
+   ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${PROJECT_NAME}Version.cmake
+   VERSION ${PROJECT_VERSION}
+   COMPATIBILITY SameMajorVersion )
+install(
+   FILES ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/${PROJECT_NAME}Version.cmake
+   COMPONENT Development
+   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME} )
+
+# Create and install the description of the libraries.
+install( EXPORT ${PROJECT_NAME}-export
+   FILE ${PROJECT_NAME}Targets.cmake
+   COMPONENT Development
+   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME} )
+
+# Install the hand-written project configuration.
+configure_file( ${CMAKE_SOURCE_DIR}/cmake/GeoModelIOConfig.cmake.in
+   ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/GeoModelIOConfig.cmake @ONLY )
+install(
+   FILES ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/GeoModelIOConfig.cmake
+   COMPONENT Development
+   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME} )
--- a/GeoModelDBManager/CMakeLists.txt
+++ b/GeoModelDBManager/CMakeLists.txt
+# Copyright (C) 2002-2019 CERN for the benefit of the ATLAS collaboration
 ################################################################################
 # Package: GeoModelDBManager
 # author: Riccardo Maria BIANCHI <rbianchi@cern.ch> - 2017
 # major updates: rbianchi@cern.ch, 2018
 ################################################################################

-cmake_minimum_required(VERSION 3.10)
-
-# Declare the package name
-project( "GeoModelDBManager" VERSION 1.0.0 LANGUAGES CXX )
-
-# External dependencies:
-find_package( Qt5 COMPONENTS Sql )
-
-# Project's settings
-set(CMAKE_CXX_STANDARD 17)
-set(CMAKE_CXX_STANDARD_REQUIRED ON)
-set(CMAKE_CXX_EXTENSIONS OFF)
-
-# Use the GNU install directory names.
-include( GNUInstallDirs ) # it defines CMAKE_INSTALL_LIBDIR
-
-# comment if you want to get debug messages in Release
-if(CMAKE_BUILD_TYPE MATCHES Release)
-    add_definitions(-DQT_NO_DEBUG_OUTPUT)
-endif(CMAKE_BUILD_TYPE MATCHES Release)
-if(CMAKE_BUILD_TYPE MATCHES RelWithDebInfo)
-    add_definitions(-DQT_NO_DEBUG_OUTPUT)
-endif(CMAKE_BUILD_TYPE MATCHES RelWithDebInfo)
-
 # Find the header and source files.
 file( GLOB SOURCES src/*.cpp )
 file( GLOB HEADERS GeoModelDBManager/*.h )

-# Set targets and properties
+# Set up the library.
 add_library( GeoModelDBManager SHARED ${HEADERS} ${SOURCES} )
 target_link_libraries( GeoModelDBManager PUBLIC Qt5::Sql )
-target_include_directories( GeoModelDBManager SYSTEM PUBLIC ${GeoModelKernel_INCLUDE_DIRS} )
 target_include_directories( GeoModelDBManager PUBLIC
   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
-   $<INSTALL_INTERFACE:include>
-)
-# Set installation of library headers
-set_property( TARGET GeoModelDBManager PROPERTY PUBLIC_HEADER ${HEADERS} )
-
-
-###################################################
-### Installation ###
-###################################################
-
-# Export as part of GeoModelIO
-install( TARGETS GeoModelDBManager EXPORT GeoModelDBManager-export LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
- PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelDBManager )
-#
-# Version the shared library. (Please update when cutting a new release!)
-#
-set(MYLIB_VERSION_MAJOR 1)
-set(MYLIB_VERSION_MINOR 3)
-set(MYLIB_VERSION_PATCH 0)
-set(MYLIB_VERSION_STRING ${MYLIB_VERSION_MAJOR}.${MYLIB_VERSION_MINOR}.${MYLIB_VERSION_PATCH})
-
-set_target_properties(GeoModelDBManager PROPERTIES VERSION ${MYLIB_VERSION_STRING} SOVERSION ${MYLIB_VERSION_MAJOR})
+   $<INSTALL_INTERFACE:include> )
+source_group( "GeoModelDBManager" FILES ${HEADERS} )
+source_group( "src" FILES ${SOURCES} )
+set_target_properties( GeoModelDBManager PROPERTIES
+   VERSION ${PROJECT_VERSION}
+   SOVERSION ${PROJECT_VERSION_MAJOR} )
+if( "${CMAKE_BUILD_TYPE}" STREQUAL "Release" OR
+   "${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo" )
+    target_compile_definitions( GeoModelDBManager PUBLIC -DQT_NO_DEBUG_OUTPUT )
+endif()
+
+# Install the library.
+install( TARGETS GeoModelDBManager
+   EXPORT ${PROJECT_NAME}-export
+   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+   COMPONENT Runtime
+   NAMELINK_SKIP )
+install( TARGETS GeoModelDBManager
+   EXPORT ${PROJECT_NAME}-export
+   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+   COMPONENT Development
+   NAMELINK_ONLY )
+install( FILES ${HEADERS}
+   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelDBManager
+   COMPONENT Development )
--- a/GeoModelErrorHandler/CMakeLists.txt
+++ b/GeoModelErrorHandler/CMakeLists.txt
-################################################################################
-# Package: GeoModelErrorHandler
-################################################################################
+# Copyright (C) 2002-2019 CERN for the benefit of the ATLAS collaboration

-cmake_minimum_required(VERSION 3.10)
-
-# Declare the package name
-project( "GeoModelErrorHandler" VERSION 1.0.0 LANGUAGES CXX )
-
-# External dependencies:
-find_package( Qt5 COMPONENTS Core )
+# Set up how CMake should handle file names given to target_sources().
+if( POLICY CMP0076 )
+   cmake_policy( SET CMP0076 OLD )
+endif()

+# Find the header files.
 file( GLOB HEADERS GeoModelErrorHandler/*.h )

-# Set targets and properties
-add_library( GeoModelErrorHandler SHARED ${HEADERS} ${SOURCES} )
-target_include_directories( GeoModelErrorHandler PUBLIC
+# Set up the library.
+add_library( GeoModelErrorHandler INTERFACE )
+source_group( "GeoModelErrorHandler" FILES ${HEADERS} )
+target_include_directories( GeoModelErrorHandler INTERFACE
   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
-   $<INSTALL_INTERFACE:include>
-)
-# Set installation of library headers
-set_property( TARGET GeoModelErrorHandler PROPERTY PUBLIC_HEADER ${HEADERS} )
-
-# Export as part of GeoModelIO
-install( TARGETS GeoModelErrorHandler EXPORT GeoModelErrorHandler-export LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
- PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelErrorHandler )
-
-#
-# Version the shared library. (Please update when cutting a new release!)
-#
-set(MYLIB_VERSION_MAJOR 1)
-set(MYLIB_VERSION_MINOR 3)
-set(MYLIB_VERSION_PATCH 0)
-set(MYLIB_VERSION_STRING ${MYLIB_VERSION_MAJOR}.${MYLIB_VERSION_MINOR}.${MYLIB_VERSION_PATCH})
-
-set_target_properties(GeoModelErrorHandler PROPERTIES VERSION ${MYLIB_VERSION_STRING} SOVERSION ${MYLIB_VERSION_MAJOR})
+   $<INSTALL_INTERFACE:include> )
+target_link_libraries( GeoModelErrorHandler INTERFACE Qt5::Core )
+if( "${CMAKE_BUILD_TYPE}" STREQUAL "Release" OR
+   "${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo" )
+   target_compile_definitions( GeoModelErrorHandler INTERFACE
+      -DQT_NO_DEBUG_OUTPUT )
+endif()
+
+# Install the library.
+install( TARGETS GeoModelErrorHandler
+   EXPORT ${PROJECT_NAME}-export
+   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+   COMPONENT Development )
+install( FILES ${HEADERS}
+   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelErrorHandler
+   COMPONENT Development )
--- a/GeoModelRead/CMakeLists.txt
+++ b/GeoModelRead/CMakeLists.txt
+# Copyright (C) 2002-2019 CERN for the benefit of the ATLAS collaboration
 ################################################################################
 # Package: GeoModelRead
 # author: Riccardo Maria BIANCHI <rbianchi@cern.ch> - 2017
 # major updates: rbianchi@cern.ch, 2018
 ################################################################################

-cmake_minimum_required(VERSION 3.10)
-
-# Declare the package name
-project( "GeoModelRead" VERSION 1.0.0 LANGUAGES CXX )
-
-### Dependencies.
-# Third-party dependencies.
-find_package( Qt5 COMPONENTS Core Sql ) # for QDebug # TODO: remove Sql dependency, which is brought by GeoModelDBManager
-# GeoModelIO dependencies.
-find_package( GeoModelCore REQUIRED )
-
-# Project's settings
-set(CMAKE_CXX_STANDARD 17)
-set(CMAKE_CXX_STANDARD_REQUIRED ON)
-set(CMAKE_CXX_EXTENSIONS OFF)
-
-# Use the GNU install directory names.
-include( GNUInstallDirs ) # it defines CMAKE_INSTALL_LIBDIR
-
-if(CMAKE_BUILD_TYPE MATCHES Release)
-    add_definitions(-DQT_NO_DEBUG_OUTPUT) # comment out if you want to get debug messages in Release
-endif(CMAKE_BUILD_TYPE MATCHES Release)
-if(CMAKE_BUILD_TYPE MATCHES RelWithDebInfo)
-    add_definitions(-DQT_NO_DEBUG_OUTPUT) # comment out if you want to get debug messages in RelWithDebInfo
-endif(CMAKE_BUILD_TYPE MATCHES RelWithDebInfo)
-
 # Find the header and source files.
 file( GLOB SOURCES src/*.cpp )
 file( GLOB HEADERS GeoModelRead/*.h )

-# Set targets and properties
+# Set up the library.
 add_library( GeoModelRead SHARED ${HEADERS} ${SOURCES} )
-target_link_libraries( GeoModelRead PUBLIC Qt5::Core GeoModelKernel GeoModelDBManager TFPersistification )
-target_include_directories( GeoModelRead SYSTEM PUBLIC ${GeoModelCore_INCLUDE_DIRS} ${GeoModelDBManager_INCLUDE_DIRS} )
+target_link_libraries( GeoModelRead PUBLIC Qt5::Core GeoModelKernel
+    GeoModelDBManager TFPersistification )
 target_include_directories( GeoModelRead PUBLIC
   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
-   $<INSTALL_INTERFACE:include>
-)
-
-# Set installation of library headers
-set_property( TARGET GeoModelRead PROPERTY PUBLIC_HEADER ${HEADERS} )
-
-# Install the library and set export target
+   $<INSTALL_INTERFACE:include> )
+source_group( "GeoModelRead" FILES ${HEADERS} )
+source_group( "src" FILES ${SOURCES} )
+set_target_properties( GeoModelRead PROPERTIES
+   VERSION ${PROJECT_VERSION}
+   SOVERSION ${PROJECT_VERSION_MAJOR} )
+if( "${CMAKE_BUILD_TYPE}" STREQUAL "Release" OR
+   "${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo" )
+   target_compile_definitions( GeoModelRead PUBLIC -DQT_NO_DEBUG_OUTPUT )
+endif()
+
+# Install the library.
 install( TARGETS GeoModelRead
-   EXPORT GeoModelReadConfig
+   EXPORT ${PROJECT_NAME}-export
   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
-   PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelRead
- )
-
-# Install a CMake description of the project/library.
-install( EXPORT GeoModelReadConfig DESTINATION cmake )
-
-# Export as part of GeoModelIO
-install( TARGETS GeoModelRead EXPORT GeoModelRead-export LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
- PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelRead )
-
-#
-# Version the shared library. (Please update when cutting a new release!)
-#
-set(MYLIB_VERSION_MAJOR 1)
-set(MYLIB_VERSION_MINOR 3)
-set(MYLIB_VERSION_PATCH 0)
-set(MYLIB_VERSION_STRING ${MYLIB_VERSION_MAJOR}.${MYLIB_VERSION_MINOR}.${MYLIB_VERSION_PATCH})
-
-set_target_properties(GeoModelRead PROPERTIES VERSION ${MYLIB_VERSION_STRING} SOVERSION ${MYLIB_VERSION_MAJOR})
+   COMPONENT Runtime
+   NAMELINK_SKIP )
+install( TARGETS GeoModelRead
+   EXPORT ${PROJECT_NAME}-export
+   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+   COMPONENT Development
+   NAMELINK_ONLY )
+install( FILES ${HEADERS}
+   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelRead
+   COMPONENT Development )
--- a/GeoModelWrite/CMakeLists.txt
+++ b/GeoModelWrite/CMakeLists.txt
-################################################################################
-# Package: GeoModelWrite
-################################################################################
-
-cmake_minimum_required(VERSION 3.10)
-
-# Declare the package name
-project( "GeoModelWrite" VERSION 1.0.0 LANGUAGES CXX )
-
-# Project's settings
-set(CMAKE_CXX_STANDARD 17)
-set(CMAKE_CXX_STANDARD_REQUIRED ON)
-set(CMAKE_CXX_EXTENSIONS OFF)
-
-# Use the GNU install directory names.
-include( GNUInstallDirs ) # it defines CMAKE_INSTALL_LIBDIR
-
-# Dependencies.
-## Third-party dependencies.
-find_package( Qt5 COMPONENTS Core Sql) # for Qt containers # TODO: remove Sql dependency, which is brought by GeoModelDBManager
-## GeoModelIO dependencies.
-find_package( GeoModelCore REQUIRED )
-
-
-if(CMAKE_BUILD_TYPE MATCHES Release)
-    add_definitions(-DQT_NO_DEBUG_OUTPUT) # comment if you need debug messages in Release
-endif(CMAKE_BUILD_TYPE MATCHES Release)
-if(CMAKE_BUILD_TYPE MATCHES RelWithDebInfo)
-    add_definitions(-DQT_NO_DEBUG_OUTPUT) # comment if you need debug messages in RelWithDebInfo
-endif(CMAKE_BUILD_TYPE MATCHES RelWithDebInfo)
-
+# Copyright (C) 2002-2019 CERN for the benefit of the ATLAS collaboration

 # Find the header and source files.
 file( GLOB SOURCES src/*.cpp )
 file( GLOB HEADERS GeoModelWrite/*.h )

-# Set targets and properties
+# Set up the library.
 add_library( GeoModelWrite SHARED ${HEADERS} ${SOURCES} )
-target_link_libraries( GeoModelWrite PUBLIC Qt5::Core GeoModelKernel GeoModelDBManager TFPersistification )
-target_include_directories( GeoModelWrite SYSTEM PUBLIC ${GeoModelCore_INCLUDE_DIRS} ${GeoModelDBManager_INCLUDE_DIRS} )
+target_link_libraries( GeoModelWrite PUBLIC Qt5::Core GeoModelKernel
+    GeoModelDBManager TFPersistification )
 target_include_directories( GeoModelWrite PUBLIC
   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
-   $<INSTALL_INTERFACE:include>
-)
-
-# Set installation of library headers
-set_property( TARGET GeoModelWrite PROPERTY PUBLIC_HEADER ${HEADERS} )
-
-# Install the library and set export target
+   $<INSTALL_INTERFACE:include> )
+source_group( "GeoModelWrite" FILES ${HEADERS} )
+source_group( "src" FILES ${SOURCES} )
+set_target_properties( GeoModelWrite PROPERTIES
+   VERSION ${PROJECT_VERSION}
+   SOVERSION ${PROJECT_VERSION_MAJOR} )
+if( "${CMAKE_BUILD_TYPE}" STREQUAL "Release" OR
+   "${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo" )
+   target_compile_definitions( GeoModelWrite PUBLIC -DQT_NO_DEBUG_OUTPUT )
+endif()
+
+# Install the library.
 install( TARGETS GeoModelWrite
-   EXPORT GeoModelWriteConfig
+   EXPORT ${PROJECT_NAME}-export
   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
-   PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelWrite
- )
-
-# Install a CMake description of the project/library.
-install( EXPORT GeoModelWriteConfig DESTINATION cmake )
-
-# Export as part of GeoModelIO
-install( TARGETS GeoModelWrite EXPORT GeoModelWrite-export LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
- PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelWrite )
-
-#
-# Version the shared library. (Please update when cutting a new release!)
-#
-set(MYLIB_VERSION_MAJOR 1)
-set(MYLIB_VERSION_MINOR 3)
-set(MYLIB_VERSION_PATCH 0)
-set(MYLIB_VERSION_STRING ${MYLIB_VERSION_MAJOR}.${MYLIB_VERSION_MINOR}.${MYLIB_VERSION_PATCH})
-
-set_target_properties(GeoModelWrite PROPERTIES VERSION ${MYLIB_VERSION_STRING} SOVERSION ${MYLIB_VERSION_MAJOR})
+   COMPONENT Runtime
+   NAMELINK_SKIP )
+install( TARGETS GeoModelWrite
+   EXPORT ${PROJECT_NAME}-export
+   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+   COMPONENT Development
+   NAMELINK_ONLY )
+install( FILES ${HEADERS}
+   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/GeoModelWrite
+   COMPONENT Development )
--- a/TFPersistification/CMakeLists.txt
+++ b/TFPersistification/CMakeLists.txt
-################################################################################
-# Package: TFPersistification
-################################################################################
-
-cmake_minimum_required(VERSION 3.10)
-
-# Declare the package name
-project( "TFPersistification" VERSION 1.0.0 LANGUAGES CXX )
-
-set(CMAKE_CXX_STANDARD 17)
-set(CMAKE_CXX_STANDARD_REQUIRED ON)
-set(CMAKE_CXX_EXTENSIONS OFF)
-
-# Use the GNU install directory names.
-include( GNUInstallDirs )
+# Copyright (C) 2002-2019 CERN for the benefit of the ATLAS collaboration

 # Find the header and source files.
 file( GLOB SOURCES src/*.cpp )
 file( GLOB HEADERS TFPersistification/*.h )

-# Dependencies.
-find_package( GeoModelCore REQUIRED )
-
-# Find an existing installation of Eigen3.
-list( APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake )
-find_package( Eigen3 REQUIRED )
-
-
-# Create the library.
+# Set up the library.
 add_library( TFPersistification SHARED ${HEADERS} ${SOURCES} )
-set_property( TARGET TFPersistification
-   PROPERTY PUBLIC_HEADER ${HEADERS} )
-
-if( BUILTIN_EIGEN3 )
-   add_dependencies( TFPersistification EIGEN3 )
-endif()
-
-target_include_directories ( TFPersistification SYSTEM PUBLIC ${GeoModelCore_INCLUDE_DIR} ${EIGEN3_INCLUDE_DIR} )
-
+target_link_libraries( TFPersistification PUBLIC
+   GeoGenericFunctions GeoModelKernel )
 target_include_directories( TFPersistification PUBLIC
   $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
   $<INSTALL_INTERFACE:include> )
+source_group( "TFPersistification" FILES ${HEADERS} )
+source_group( "src" FILES ${SOURCES} )
+set_target_properties( TFPersistification PROPERTIES
+   VERSION ${PROJECT_VERSION}
+   SOVERSION ${PROJECT_VERSION_MAJOR} )
+if( "${CMAKE_BUILD_TYPE}" STREQUAL "Release" OR
+   "${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo" )
+    target_compile_definitions( TFPersistification PUBLIC
+      -DQT_NO_DEBUG_OUTPUT )
+endif()

-target_link_libraries( TFPersistification PUBLIC GeoModelKernel )
-
-# Export as part of GeoModelIO
-install( TARGETS TFPersistification EXPORT TFPersistification-export LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
- PUBLIC_HEADER DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/TFPersistification )
-
-#
-# Version the shared library. (Please update when cutting a new release!)
-#
-set(MYLIB_VERSION_MAJOR 1)
-set(MYLIB_VERSION_MINOR 3)
-set(MYLIB_VERSION_PATCH 0)
-set(MYLIB_VERSION_STRING ${MYLIB_VERSION_MAJOR}.${MYLIB_VERSION_MINOR}.${MYLIB_VERSION_PATCH})
-
-set_target_properties(TFPersistification PROPERTIES VERSION ${MYLIB_VERSION_STRING} SOVERSION ${MYLIB_VERSION_MAJOR})
+# Install the library.
+install( TARGETS TFPersistification
+   EXPORT ${PROJECT_NAME}-export
+   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+   COMPONENT Runtime
+   NAMELINK_SKIP )
+install( TARGETS TFPersistification
+   EXPORT ${PROJECT_NAME}-export
+   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+   COMPONENT Development
+   NAMELINK_ONLY )
+install( FILES ${HEADERS}
+   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/TFPersistification
+   COMPONENT Development )
--- a/cmake/GeoModelIOConfig.cmake
+++ b/cmake/GeoModelIOConfig.cmake
-get_filename_component(SELF_DIR "${CMAKE_CURRENT_LIST_FILE}" PATH)
-# include(${SELF_DIR}/GeoModelIO-GeoModelErrorHandler.cmake)
-include(${SELF_DIR}/GeoModelIO-GeoModelDBManager.cmake)
-include(${SELF_DIR}/GeoModelIO-TFPersistification.cmake)
-include(${SELF_DIR}/GeoModelIO-GeoModelRead.cmake)
-include(${SELF_DIR}/GeoModelIO-GeoModelWrite.cmake)
--- a/cmake/GeoModelIOConfig.cmake.in
+++ b/cmake/GeoModelIOConfig.cmake.in
+# Copyright (C) 2002-2019 CERN for the benefit of the ATLAS collaboration
+
+# First off, import the upstream dependencies of the project.
+find_package( Qt5 COMPONENTS Core Sql )
+find_package( GeoModelCore )
+
+# Now include the exported configuration of GeoModelIO.
+get_filename_component( SELF_DIR "${CMAKE_CURRENT_LIST_FILE}" PATH )
+include( ${SELF_DIR}/GeoModelIOTargets.cmake )
+
+# Set the version of the installed project.
+set( GeoModelCore_VERSION "@PROJECT_VERSION@" )
+
+# Print some standard messages about the package being found.
+include( FindPackageHandleStandardArgs )
+find_package_handle_standard_args( GeoModelIO
+   FOUND_VAR GeoModelIO_FOUND
+   REQUIRED_VARS SELF_DIR Qt5_FOUND GeoModelCore_FOUND
+   VERSION_VAR GeoModelCore_VERSION )
+
+# Clean up.
+unset( SELF_DIR )